Diese Seiten werden seit dem 1. 10. 22. nicht mehr gepflegt und aktualisiert. Die Inhalte bleiben weiterhin abrufbar.

Einkommensteuer


X
X
X
X
X
X
X
X
X
X
X
X
X
X
X
X
X
X

Anleitung zum Erstellen einer Zellfunktion in EXCEL zur Berechnung der Einkommensteuer

Die Berechnung der Einkommensteuer ist entsprechend den gesetzlich vorgegeben Formeln durchzuführen.

Da es mehrere Einkommensbereiche mit unterschiedlichen Steuersätzen zu berücksichtigen gilt, erstellt man für eine solche Excel Zellfunktion zweckmäßigerweise zunächst für die einzelnen Bereiche gesonderte Formeln, prüft diese für sich und fügt diese erst dann zu einer Summen- oder verschachtelten Formel zusammen.

Zur Berechnung der Einkommensteuer entsprechend obiger Vorgaben werden folgende Funktionen von EXCEL benötigt:

WENN und
UND sowie
GANZZAHL (da die Einkommensteuer immer auf volle (Euro)Beträge abgerundet wird, was die Funktion GANZZAHL bewirkt):

WENN hat folgende Form (Bereiche durch Semikolon getrennt):
=WENN(Bedingung;Ergebnis wenn Bedingung zutrifft; E. wenn Bedingung nicht zutrifft)
sowie UND:
UND(Bedingung;Bedingung) (wenn beide zutreffen=Bedingung erfüllt, wenn nur eine oder garkeine dann = Bedingung nicht erfüllt)

Genauere Erklärungen zu den Funktionen findet man im EXCEL-Programm selbst. Dazu (zunächst irgendeine Zelle anklicken und) den Funktions-Assistent aufrufen (Icon fx anklicken). Dadurch öffner sich das Fenster "Funktion einfügen". Dort die LOGIK-Funktionen anklicken (linke Seite) und rechts z.B. die Funktion WENN. Dann das Fragezeichen Icon (links unten) anklicken und "Hilfe zu diesem Feature" erbitten. In dem dann sich öffnenden Fenster ist der Gebrauch der WENN-Funktion näher erkärt. Gleiches gilt für die anderen Funktionen.

Wer sich zunächst erst noch eingehender über die Tabellenkalkulation mit EXCEL informieren will, sei auf eine .pdf-Datei (2.2 MB) verwiesen:Tabellenkalkulation in EXCEL. Dort werden auf 116 Seiten nützliche Grundlagen vermittelt. So z.B. über den Gebrauch der WENN-Funktion und vieles mehr. Sehr empfehlenswert!

Auch sehr empfehlenwert, weil zur Erstellung einer EXCEL-Lohnbuchhaltung gut zu gebrauchen: Beispiele von wichtigen Zellfunktionen unter http://www.castelligasse.at/excel/excel.htm. Eine weitere empfehlenswerte Einführung in EXCEL kann man herunterladen unter EXCEL Aufbaukurs (2,1 MB).

Entsprechend dem Gesetzestext für z.B. die Einkommensteuer 2004 formulieren wir zunächst

für y = (Zellenwert-7664)/10000
für z = (Zellenwert-12739)/10000

und diese Werte einsetzend

für bis 7 664 Euro (Grundfreibetrag): 0
ist die Formel dementsprechend:
=WENN(Zellenwert < 7665;0;0) (kann man eigentlich weglassen)

für von 7 665 Euro bis 12 739 Euro: (793,10 · y + 1 600) · y;
=WENN(UND(Zellenwert > 7664;Zellenwert < 12740);GANZZAHL((793,1*(Zellenwert - 7664)/10000+1600)*(Zellenwert-7664)/10000);0)

für von 12 740 Euro bis 52 151 Euro: (265,78 · z + 2 405) · z + 1016
=WENN(UND(Zellenwert > 12739;Zellenwert < 52152);GANZZAHL((265,78*(Zellenwert - 12739)/10000 + 2405)*(Zellenwert - 12739)/10000 + 1016);0)

für von 52 152 Euro an: 0,45 · x – 8 845.
=WENN(Zellenwert > 52151;GANZZAHL(Zellenwert*0,45-8845);0)

Wie man sieht, muß man beachten, daß bei < und > nur jeweils ein um eins erhöhter/erniedrigter Wert in die Formel eingesetzt werden darf, um richtig zu rechnen (bei >= und <= kann man die Werte aus dem Steuergesetz direkt übernehmen). Zur Überprüfung, ob die einzelnen Formeln richtig sind, wird EXCEL aufgerufen, irgendeine Zelle angeklickt(aktiviert) und entweder die erstellte Formel komplett in die Zelle geschrieben (Wichtig: statt Zellenwert muß natürlich eine Zellbezeichnung, in der das Einkommen stehen wird (z.B. B5), eingegeben werden), oder (was zur Überprüfung besser ist) zunächst der Funktions-Assistent in EXCEL aufgerufen (Icon fx) und dort die einzelnen (in der Formel durch Semikolon getrennten) Bereiche in die Felder nacheinander eingetragen (mit gewünschter Zellbezeichnung). In dem Einkommensbereich, in dem die gewählte Formel gilt, muß dann ein Ergebnis in der aktivierten Zelle erscheinen (wenn man zuvor das dazu passende Einkommen z.B. in Zelle B5 eingegeben hat) bzw. 0, wenn der Bereich nicht zutrifft.

Wenn die einzelnen Formeln überprüft sind, werden sie dann hintereinander mit Pluszeichen einfach als Summe zusammengefügt:

=WENN(Zellenwert < 7665;0;0) + WENN(UND(Zellenwert > 7664;Zellenwert < 12740);GANZZAHL((793,1*(Zellenwert - 7664)/10000+1600)*(Zellenwert-7664)/10000);0) + WENN(UND(Zellenwert > 12739;Zellenwert < 52152);GANZZAHL((265,78*(Zellenwert - 12739)/10000 + 2405)*(Zellenwert - 12739)/10000 + 1016);0) + WENN(Zellenwert > 52151;GANZZAHL(Zellenwert*0,45-8845);0)

Wenn man den Ausdruck "Zellenwert" z.B. durch B5 (als Eingabezelle) ersetzt und die erste Bedingung (graue Farbe) wegläßt (da sich die Summe ja dadurch nicht verändert), ergibt sich folgende Formel (die man so in eine Zelle eines Arbeitsblattes kopieren kann):

=WENN(UND(B5>7664;B5<12740);GANZZAHL((793,1*(B5 - 7664)/10000+1600)*(B5-7664)/10000);0) + WENN(UND(B5>12739;B5 < 52152);GANZZAHL((265,78*(B5 - 12739)/10000 + 2405)*(B5 - 12739)/10000 + 1016);0) + WENN(B5>52151;GANZZAHL(B5*0,45-8845);0)

Obwohl kaum kürzer, wird gerne eine andere, nämlich die verschachtelte Formel gewählt, indem man mit der ersten Formel beginnend, die nächste immer an 3. Stelle der WENN-Funktion (Bedingung nicht erfüllt) - in unserem Fall statt der 0 also - eingefügt:

= WENN(Zellenwert < 7665;0; WENN(UND(Zellenwert > 7664;Zellenwert < 12740);GANZZAHL((793,1*(Zellenwert - 7664)/10000+1600)*(Zellenwert-7664)/10000); WENN(UND(Zellenwert > 12739;Zellenwert < 52152);GANZZAHL((265,78*(Zellenwert - 12739)/10000) + 2405)*(Zellenwert - 12739)/10000 + 1016) ; WENN(Zellenwert > 52151;GANZZAHL(Zellenwert*0,45-8845);0 ))))

Die fertige Einkommensteuerberechnungsformel mit B5 als Eingabezelle (erste Bedingung -grau gefärbt- wieder weggelassen) sieht dann so aus:

=WENN(UND(B5>7664;B5<12740); GANZZAHL((793,1*(B5-7664)/10000+1600)*(B5-7664)/10000); WENN(UND(B5>12739;B5<52152);GANZZAHL((265,78*(B5-12739)/10000+2405)*(B5-12739)/10000+1016); WENN(B5>52151;GANZZAHL(B5*0,45-8845);0)))

Auf die UND()-Funktion zur Eingrenzung des Bereichs kann man verzichten, wenn man die Funktion jeweils nur mit den oberen Bereichsgrenzen formuliert. Den steuerfreien Bereich muss man dann aber auch berücksichtigen. Die Formel ab 2010 verkürzt sich dann entsprechend auf:

=WENN(B5<8004;0; WENN(B5<13470;GANZZAHL((912,17*(B5-8004)/10000+1400)*(B5-8004)/10000); WENN(B5<52882;GANZZAHL((228,74*(B5-13469)/10000+2397)*(B5-13469)/10000+1038); WENN(B5<250731;GANZZAHL(B5*0,42-8172); GANZZAHL(B5*0,45-15694)))))

Diese Berechnung gilt für den Grundtarif. Für den Splittingtarif wird nur von der Hälfte des Einkommens die Steuer berechnet, diese muß anschließend dann aber verdoppelt werden. Für die Zellformel bedeutet dies, daß bei dem Beispiel statt dem Zellwert B5 nur der abgerundete halbe Zellwert = GANZZAHL(B5/2) eingesetzt wird und die Ergebnisse (d. h. die zutreffend-Teile) mit 2 wieder multipliziert werden. Das sieht dann so aus (Veränderung fett):

=WENN(UND(B5/2>7664;B5/2<12740);(GANZZAHL((793,1*(GANZZAHL(B5/2)-7664)/10000+1600)*(GANZZAHL(B5/2)-7664)/10000))*2; WENN(UND(B5/2>12739;B5/2<52152);(GANZZAHL((265,78*(GANZZAHL(B5/2)-12739)/10000+2405) *(GANZZAHL(B5/2)-12739)/10000+1016))*2; WENN(B5/2>52151;(GANZZAHL(GANZZAHL(B5/2)*0,45-8845))*2;0)))

Die entsprechende Formel für den Splittingtarif ohne UND()-Funktion lautet dann (ab 2010):

=WENN(B5/2<8004;0;WENN(B5/2<13470;GANZZAHL((912,17*(GANZZAHL(B5/2)-8004)/10000+1400)*(GANZZAHL(B5/2)-8004)/10000);WENN(B5/2<52882;GANZZAHL((228,74*(GANZZAHL(B5/2)-13469)/10000+2397)*(GANZZAHL(B5/2)-13469)/10000+1038) ;WENN(B5/2<250731;GANZZAHL(GANZZAHL(B5/2)*0,42-8172);GANZZAHL(GANZZAHL(B5/2)*0,45-15694)))))*2

Wenn man die Einkommensteuerberechnung nicht in einer einzige Zellfunktion mit der entsprechend notwendigen Verschachtelung zusammenführen möchte, kann man die für die einzelnen Einkommensbereiche und für x und y formulierten Zellfunktionen natürlich jeweils in einer eigenen Zelle belassen und in einer weiteren Funktion dann diese Zellen zur Einkommensteuerberechnung verbinden. Ein Beispiel dafür ist unter http://www.mathematik-online.de/F89.htm zu finden.

Unter ekstexcel.xls sind die vorgestellten Zellformeln in ein EXCEL-Arbeitsblatt integriert.

Erstellen einer Einkommensteuertabelle

Mit der Zellfunktion kann man dann auch seine eigene Einkommensteuertabelle erstellen. Man braucht übrigens die Zellfunktion nicht mit Angabe der jeweiligen Zelle, in der das Einkommen steht, für jede Zeile neu schreiben. Es genügt 1x. Dann diese Zelle kopieren, die ganze Zellspalte darunder aktivieren und dann die kopierte Zellfunktion einfügen. EXCEL ändert automatisch die Zeilenangabe in jeder Zelle. Auch um eine Spalte mit ansteigendem Einkommen, dessen Intervalle man vorgeben kann, zu erzeugen, muß man nicht jede Zeile einzeln formulieren. Ein Beispiel, wie man das machen kann, findet man unter zelltab.xls .

Erstellen der Zellfunktion für 2022

Der Grundfreibtrag für 2022 wurde mit dem PAP vom 20. 5. 22. ab 1. Juni 2022 rückwirkend für das ganze Jahr auf 10347 € angehoben. Die Konstante der 1. Progressionsstufe beträgt 1088,70 €. Ursprünglich lag der Grundfreibtrag 2022 bei 9984 € und die 1. Progressionsstufe bei 1008,70 €. Weitere Werte sind entsprechend angepasst.

Die neuen Tarife sind unter Steuersätze seit 1958 zu finden bzw. auch im EXCEL Arbeitsblatt ekstexcel.xls als Zellfunktion zur Berechnung der Einkommensteuer 2013 bis 2020 eingefügt.

Erstellen der Zellfunktion für 2021

Der Grundfreibtrag für 2021 wurde auf 9744 € angehoben. Die Konstante der 1. Progressionsstufe beträgt 995,21 €. Weitere Werte sind entsprechend angepasst.

Erstellen der Zellfunktion für 2020

Der Grundfreibtrag für 2020 wurde auf 9408 € angehoben. Die Konstante der 1. Progressionsstufe beträgt 972,87 €. Weitere Werte sind entsprechend angepasst.

Erstellen der Zellfunktion für 2019

Der Grundfreibtrag für 2019 wurde auf 9168 € angehoben. Die Konstante der 1. Progressionsstufe beträgt 980,14 €. Weitere Werte sind entsprechend angepasst.

Erstellen der Zellfunktion für 2018

Der Grundfreibtrag für 2019 wurde auf 9000 € angehoben. Die Konstante der 1. Progressionsstufe beträgt 997,8 €. Weitere Werte sind entsprechend angepasst.

Erstellen der Zellfunktion für 2017

Der Grundfreibtrag für 2017 wurde auf 8820 € angehoben. Die Konstante der 1. Progressionsstufe beträgt 1007,27 €. Weitere Werte sind entsprechend angepasst.

Erstellen der Zellfunktion für 2016

Der Grundfreibtrag wurde für 2017 auf 8820 € angehoben. Die Konstante der 1. Progressionsstufe beträgt 1007,27 €. Weitere Werte sind entsprechend angepasst.

Erstellen der Zellfunktion für 2015

Mit dem Gesetz zur Anhebung des Grundfreibetrags, des Kinderfreibetrags, des Kindergeldes und des Kinderzuschlags vom 16. Juli 2015 wurde der Grundfreibtrag rückwirkend für 2015 auf 8472 € und die Konstante der 1. Progressionsstufe auf 997,60 € angehoben. Weitere Werte sind entsprechend angepasst.

Erstellen der Zellfunktion für 2013 bis 2014

Am 1.2.2013 Drucksache 35/13 hat der Bundesrat dem Gesetzesvorschlag der Bundesregierung vom 17.1.2013 zugestimmt. Damit erhöht sich der Grundfreibetrag 2013 auf 8.130 € und 2014 auf 8354 €. Weitere Werte sind entsprechend angepasst.

Erstellen der Zellfunktion für 2009 und 2010-12

Für 2009 und für 2010 - 12 wurden folgende Änderungen des Einkommensteuertarifs beschlossen: Einganssteuersatz 14%, Grundfreibetrag 7.834 € (2009) bzw. 8.004 € (ab 2010), Verschiebung der weiteren Eckwerte um je 400 € (2009) bzw 330 € (ab 2010) nach rechts. Die entsprechenden Tarifformeln sind zu finden im Gesetz zur Sicherung von Beschäftigung und Stabilität in Deutschland (BGBl Teil I, 2009, Nr. 11, (4), vom 5.03.2009). Die neuen Tarife sind auch im EXCEL Arbeitsblatt ekstexcel.xls als Zellfunktion zur Berechnung der Einkommensteuer 2009 bzw. ab 2010 eingefügt.

Erstellen der Zellfunktion für 2008

Zellfunktion wie 2007. Die besondere Besteuerung von Gewinneinkünften entfällt wieder.

Erstellen der Zellfunktion für 2007

Zur Berechnung der Einkommensteuer 2007 muss die Zellfunktion von 2005/06 um die Berechnung der "Reichensteuer" (für Einkommen über 250.000/500.000 Euro - wenn es nicht Gewinne sind) erweitert werden, d.h. um die Berechnung zvE *0.45 - 15414 bei Beträgen über 250.000.

Dazu wird bei dem (am Ende stehenden) Ausdruck der Zellfunktion für 2005/06 WENN(B5>52151;GANZZAHL(B5*0,42-7914);0) statt B5>52151 der Bereich UND(B5>52151;B5<250001) eingesetzt und die 0 entsprechend durch die Berechnung der "Reichensteuer" ersetzt:

WENN(UND(B5>52151;B5<250001);GANZZAHL(B5*0,42-7914) ; WENN(B5>250000;GANZZAHL(B5*0,45-15414);0))

Mit Einsetzten von B5/2 und Halbierung des zutreffend-Teils kann man dann auch wieder analog den Splittingtarif errechnen. Die fertigen Zellfunktionen für 2007 sind in das EXCEL Arbeitsblatt ekstexcel.xls eingefügt.

Wenn es sich bei den Einkünften um Gewinne handelt entsprechend § 2 Abs. 1 Nr. 1-3 EStG, dann werden diese 2007 nach wie vor mit nur 42% besteuert, d.h. wenn nur Gewinne zu versteuern sind, ist die Zellfunktion von 2005/06 zu benutzen.

Für den Fall, dass die Gesamteinkünfte sich aus beiden Einkunftsarten zusammensetzten, wird nach dem neuen § 32c EStG (Tarifbegrenzung bei Gewinneinkünften) der mit 45% zu versteuernde Anteil der 250.000 Euro übersteigenden Einkünfte aus dem Verhältnis der beiden Einkunftsarten ermittelt und davon 3% wieder von der Gesamtsteuer abgezogen:

Beispiel: 312.500 Euro Gesamteinkünfte, davon 150.000 Euro Gewinne und 12.500 Euro Sonderausgaben. Die 250.000 Euro übersteigende Einkünfte (d.h. 50.000 Euro) werden auf Grund des Verhältnises der Gewinneinkünfte zu den Gesamteinkünften in diesem Beispiel entsprechend nur im Verhältnis 150.000/312.500 mit 45% belastet, d.h. von den mit der Zellfunktion (mit 45%) ermittelten Steuer (300.000 x 45% - 15.414 = 119.586) werden wieder 24.000 ( die sich ergeben durch: (300.000 - 250.000) x 150.000/312.500) x 3% = 720 Euro abgezogen. Die zu zahlende Steuer ist demnach 119.586 - 720 = 118.866 Euro. Diese Berechnung bewerkstelligt man praktischerweise mit einer weiteren Zelle mit der entsprechenden Zellfunktion. Wer erstellt diese selbst?

Kontakt Formular

Kontakt Information

Diese Website dient ausschließlich der allgemeinen Information und erhebt keinen Anspruch auf Richtigkeit und Vollständigkeit. Bitte beachten Sie, dass wir keine steuerrechtlichen Fragen beantworten können. In diesem Fall bitten wir Sie sich an Ihren zuständigen Steuerberater zu wenden.

© 2021 by Johannes Parmentier | designed & supported by KAYSTONE GmbH | Datenschutz